tuto

Galerie d’ image en AS3 et XML

Ce tutoriel va vous apprendre à manipuler en ActionScript 3 un document XML afin d’en extraire du contenu. Nous ferons appel à plusieurs outils de Flash avec la classe Tween (qui nous permettra de réaliser des effets) et d’autres composants comme les UILoader intégrés à Flash.

 

Ce tutoriel est exclusivement un tutoriel de programmation dans le sens ou nous allons utiliser Flash juste pour son éditeur de code. Je voudrais aussi signaler l’origine de ces images qui proviennent du fabuleux collectif Dephtcore.

Etape 1: Organisation

Avant toute chose il est essentiel de prévoir comment nous allons arranger la structure de notre application. Nous aurons donc à la racine de notre application 3 Fichiers (notre fichier flash .fla, notre exécutable .swf, et enfin le fichier XML). Le dossier quant à lui contient toutes les photos de notre galerie. Ce dossier contiendra lui-même un dossier de miniatures (dont les noms des images seront les mêmes que pour les originaux). Cela devrait donner ceci:

Arborescence

Etape 2: Le Document XML

Si vous n’avez jamais entendu parler ou utiliser de XML, cela ne devrait pas nuire au tutoriel. En fait voyez-le comme un langage qui vous permettrait de structurer vos données. Un peu comme de l’xHTML ou vous appeleriez vos balises comme bon vous semble (xHTML est en fait de l’XML…). Bref nommez votre fichier galerie.xml contenant cette structure:

<img src="underwater.jpg" alt="DepthCore - Underwater (David)" />
<img src="retro_pheromone.jpg" alt="DepthCore - Retro Pheromone (Jinberdeem)" />
<img src="hocus_pocus.jpg" alt="DepthCore - Hocus pocus (Surpy)" />
<img src="torment.jpg" alt="DepthCore - Torment (Radu Pop)" />
<img src="lola.jpg" alt="DepthCore - Lola (Caramelow)" />
<img src="delicacy.jpg" alt="DepthCore - Delicacy (Rogue)" />
<img src="local_seduction.jpg" alt="DepthCore - Local seduction (Jinberdeem)" />
<img src="blok_party.jpg" alt="DepthCore - Blok party (83Grafik)" />

Nous aurons donc une balise « galerie » comportant plusieurs balises « image » ayant eux-mêmes 2 attributs: « src » et « alt » (très inspiré des attributs HTML). l’attribut « src » contient la source de l’image (autrement dit son nom), tandis que « alt » informe sur le texte alternatif.

Pourquoi utiliser XML?

La nécessité d’avoir un document XML pour notre galerie d’images répond principalement à 2 objectifs. D’une part, pour rajouter une image à notre galerie, nous ne sommes pas obligé d’avoir Flash, un bloc-notes suffit. Bien que cet argument tombe à l’eau si nous utilisions un fichier ActionScript externe. Le second avantage est étant donné la popularité du XML celui-ci peut être lu et interprété par une multitude de langage comme PHP, Javascript… Nous pourrions donc avoir un seul fichier contenant toutes les sources pour toutes les applications.

Etape 3: Prémices au développement

Nous allons utiliser uniquement la partie « développement » de Flash, et tout manipuler à l’aide du langage ActionScript 3. Tout d’abord créez un document Flash AS3, puis dans les propriétés redimensionnez-le à 800px par 450 px puis dans le scénario faites un clic droit sur la première image et choisissez « Actions », Une fenêtre s’ouvrira, c’est ici que vous coderez votre application.

La première étape va consister à importer les classes qui nous intéressent pour la suite…

import flash.net.URLLoader;
import flash.net.URLRequest;
import fl.containers.UILoader;
import fl.controls.ProgressBar;
import fl.transitions.Tween;
import fl.transitions.easing.*;
import fl.transitions.TweenEvent;
import flash.events.*;
import flash.text.*;
import flash.filters.*;

Etape 4: Les fonctionnalités à programmer

Cette étape va consister à définir les fonctions dont nous allons avoir besoin, Il y’en aura 5 au total:

  1. Initialisation de l’application (lorsque le fichier XML est totalement chargée) -> « finDuChargementXML() »
  2. Changement d’images -> « changeImage() »
  3. Survol de la miniature (effets graphiques que nous allons appliquer) -> « overImage() »
  4. Clic sur la miniature -> « clicImage() »
  5. Quand on quitte la miniature -> « outImage() »

Avant de commencer à développer ces fonctions il va falloir commencer par initialiser les composants dont on aura besoin, de charger le fichier XML, les constantes, etc.

//Constantes
var dossierImage:String = 'images/';
var dossierImageMini:String = 'images/min/';

//Chargeur qui téléchargera notre fichier XML
var chargeur:URLLoader = new URLLoader ();
//objet URLRequest qui contient l'url du fichier XML:
var adresse:URLRequest = new URLRequest ("galerie.xml");

chargeur.load(adresse);
chargeur.addEventListener(Event.COMPLETE, finDuChargementXML);

//Variable contenant le texte alternatif
var alt:String;

/*Style utilisé pour le texte Alternatif*/
var formatTitre:TextFormat = new TextFormat;
   formatTitre.color = 0x888888;
   formatTitre.size = 17;
   formatTitre.font = 'tahoma';
   formatTitre.align = 'center';

//Champ texte pour le texte alternatif
var texteAlt:TextField = new TextField();
   texteAlt.text = '';
   texteAlt.x = 325;
   texteAlt.y = 425;
   texteAlt.width = 400;
this.addChild(texteAlt);

//Champ texte pour le message de chargement
var chargement:TextField = new TextField();
   chargement.text = 'Chargement en cours...';
   chargement.setTextFormat(formatTitre);
   chargement.width = 200;
   chargement.x = 350;
   chargement.y = 200;
this.addChild(chargement);

Ce bout de code permet donc de charger le fichier XML à l’aide de la classe URLLoader et de lui attribuer un évènement « Event.COMPLETE » qui éxécutera la fonction finDuChargementXML() lorsque le fichier XML sera totalement téléchargé. On en profite aussi pour créer 2 champs TexteField correspondant aux textes de Chargement et de Description.

Etape 5: Initialisation de la galerie

Cette étape est la plus importante, et va consister à créer la base de notre application avec comme support les données de notre document XML. Voici le code, je l’explique plus bas :

/*Une fois que le fichier XML est chargé...*/
function finDuChargementXML(evt:Event):void{
   //Objet XML
   var monXML:XML = new XML(evt.target.data);
   //UILoader qui contiendra l'image originale
   var photoPrincipale:UILoader = new UILoader();
   photoPrincipale.source = dossierImage+monXML.image[1].attribute("src");
   photoPrincipale.x = 280;
   photoPrincipale.y = 10;
   photoPrincipale.scaleContent = false;

   var translation:Array = [photoPrincipale.x, photoPrincipale.x+ 100];

   //Variable qui contiendra l'image qui est selectionnée
   var select:String;

   texteAlt.text = monXML.image[1].attribute("alt");
   texteAlt.setTextFormat(formatTitre);

   //On attache le Loader à la scene
   this.addChild(photoPrincipale);

   /*Pour les miniatures*/
   for(var i:String in monXML.image) {
     var uil:UILoader = new UILoader();
     uil.source = dossierImageMini+monXML.image[i].attribute("src");
     uil.buttonMode=true;
     uil.name = i;
     uil.x = 10;
     uil.y = 10;
     uil.y += int((int(i)/3))*90;

     if(int(i)%3!=0){
       uil.x += (int(i)%3)*90;
     }

     uil.width = uil.height = 70;
     uil.alpha = 0.5;
     uil.scaleContent= true;
     uil.autoLoad = true;

     //Les écouteurs sur les miniatures
     uil.addEventListener(MouseEvent.CLICK,clicImage);
     uil.addEventListener(MouseEvent.MOUSE_OVER,overImage);
     uil.addEventListener(MouseEvent.MOUSE_OUT,outImage);
     this.addChild(uil);
   }
}

La fonction prend obligatoirement en paramètre un Evènement puisqu’il est issu de « Event.COMPLETE« . Cet évenement contient les données brutes du document XML grâce à sa propriété target.data. Il faut donc créer ensuite un objet XML pour faciliter le parsage de celui-ci. Par la suite nous créons un composant UILoader contenant la première photo.

Pour parser un fichier XML en AS3, c’est une chose assez simple: il faut avoir à l’esprit qu’il faut zapper la balise « racine », c’est à dire galerie. Voici comment on accède à l’attribut d’une balise:

monObjetXML.maBaliseImage[positionDeLaBalise].attribute('src');

L’utilisation est donc logique et assez similaire à SimpleXML, si vous utilisez PHP. Cela se corse légèrement pour les miniatures qu’il faut positionner dynamiquement. Pour faire une boucle sur toutes les images de notre fichier XML, la syntaxe est un peu plus particlière, la variable « i » correspondant à la position de la balise, 0 étant la première image. Enfin à ces miniatures, on leur ajoute 3 écouteurs : un clic, un mouseover et ou mouseout.

Etape 5: Fonctionnalités sur les miniatures / Tween

/*Quand on clique sur une miniature...*/
function clicImage(e:Event):void{
   //e.currentTarget.name correspond à la position de l'image

   //Si l'image sur laquelle on a cliquée est déjà selectionnée, il ne se passe rien....
   if(select == monXML.image[e.currentTarget.name].attribute("src")){
      return;
   }

   select = monXML.image[e.currentTarget.name].attribute("src");
   alt = monXML.image[e.currentTarget.name].attribute("alt");

   var myTweentText:Tween = new Tween(texteAlt, "alpha", Strong.easeOut, 1, 0, 1, true);
   var myTweenA:Tween = new Tween(photoPrincipale, "alpha", Strong.easeOut, 1, 0, 1, true);
   var myTweenPPW:Tween = new Tween(photoPrincipale, "x", Strong.easeIn, translation[0], translation[1],1, true);
   var myTweenPPA:Tween = new Tween(photoPrincipale, "alpha", Strong.easeIn, 1, 0, 1, true);
   myTweenA.addEventListener(TweenEvent.MOTION_FINISH, changeImage);
}

/*Quand on passe la souris sur une miniature...*/
function overImage(e:Event):void{
   //Ombre sur miniatures
   var monOmbre:DropShadowFilter = new DropShadowFilter();
   monOmbre.distance = 3;
   monOmbre.color = 0xAAAAAA;
   monOmbre.blurX = 5;
   monOmbre.blurY = 5;
   monOmbre.quality = 3;
   e.currentTarget.filters = [monOmbre];

   //Effets cools de transitions
   var myTweenMA2:Tween = new Tween(e.currentTarget, "alpha", Strong.easeOut, 0.5, 1, 1, true);
   var myTweenMW2:Tween = new Tween(e.currentTarget, "width", Elastic.easeOut, e.currentTarget.width, 75, 1, true);
   var myTweenMH2:Tween = new Tween(e.currentTarget, "height", Elastic.easeOut, e.currentTarget.height, 75, 1, true);
}

/*Quand on quitte la miniature*/
function outImage(e:Event):void{
   //Ombre sur miniatures
   var monOmbre:DropShadowFilter = new DropShadowFilter();
   monOmbre.distance = 0;
   monOmbre.color = 0x888888;
   monOmbre.blurX = 0;
   monOmbre.blurY = 0;
   monOmbre.quality = 3;
   e.currentTarget.filters = [monOmbre];
   //Effets cools de transitions
   var myTweenMA:Tween = new Tween(e.currentTarget, "alpha", Strong.easeOut, 1, 0.5, 1, true);
   var myTweenMW:Tween = new Tween(e.currentTarget, "width", Elastic.easeOut, e.currentTarget.width, 70, 1, true);
   var myTweenMH:Tween = new Tween(e.currentTarget, "height", Elastic.easeOut, e.currentTarget.height, 70, 1, true);
}

Pour ce code, rien de bien particulier, si ce n’est l’utilisation de la classe Tween qui fait son apparition: elle permet de faire des transitions de manière très simple, voici sa synthaxe:

var maTransition:Tween = new Tween(
l’objet sur lequel on applique l’effet ,
la propriété à changer ,
la classe de transition à utiliser ,
la valeur de Départ ,
la valeur Finale ,
le temps de la transition en secondes ,
booléen qui détermine si la durée est en image ou en secondes
);

Voilà après de vous amuser :) , Enfin notez la méthode qui vous permet de savoir a quelle image correspond la miniature: dans ma fonction finDeChargement, j’avais attribué une propriété name à chacune d’entre-elles et correspondant à leur position dans le document XML. Ce qui facilite la tâche. Vous n’aurez qu’à la réutiliser en utilisant e.currentTarget.name.

Etape 6: Fonction changeImage

/*Quand on veut changer d'image (logiquement après avoir cliqué sur une miniature)*/
function changeImage(e:Event):void{
   //On change la source de l'image
   photoPrincipale.source = dossierImage+select;

   //On change le texte descriptif
   texteAlt.text = alt;
   texteAlt.setTextFormat(formatTitre);

   //Et la photo arrive de façon élégante
   var myTweenPPA2:Tween = new Tween(photoPrincipale, "alpha", Strong.easeOut, 0, 1, 1, true);
   var myTweenPPW2:Tween = new Tween(photoPrincipale, "x", Strong.easeOut, translation[1], translation[0], 1, true);
   var myTweentText2:Tween = new Tween(texteAlt, "alpha", Strong.easeOut, 0, 1, 1, true);
}

Pas grand chose à signaler pour cette dernière étape, nous changeons la propriété source de notre UILoader principal et le texte du champ alternatif.

J’espère que ce tuto vous aura appris certains trucs, en tout cas tout le code source est comme d’habitute là ou il faut <(^^,)>.

115 commentaires

S'abonner au RSS des commentaires
  1. Iowah
    Posté le 04/10/2011 à 15h42

    Très bon tuto qui apprend pas mal de choses utiles ! un grand merci ! =)

    Juste une question, faut t’il rajouter sur la scène puis supprimer les composantes UiLoader et ProgressBar ?
    Car flash me signale des erreurs comme quoi ces deux méthodes ne sont pas définies.

  2. Metropeel
    Posté le 19/08/2011 à 13h26

    Merci beaucoup pour cet excellent tutoriel !
    Votre code est très précis et en un rien de temps, j’ai compris comment récupérer des données XML avec Flash.

  3. JrM
    Posté le 07/03/2011 à 19h33

    Tres bon tuto.

    Cependant, il nécessite un travaille en amonts pour les miniature ( il faut les faire soit meme) , et l’apercu ne permet pas de mettre dans ses fichiers racine de grandes image 2048*1500 par exemple. Ce qui lorsque l’on souhaite mettre des photo pose un léger probleme big_smile

    Mais merci de l’aide !!!

  4. Gianni
    Posté le 07/03/2011 à 16h40

    Génial ! Merci pour ce tuto. Rien de mieux que le bon vieux XML pour ce genre de chose.

  5. jean Pierre
    Posté le 12/02/2011 à 0h24

    Bonjour,

    tout l’album se lance correctement…. un grand merci d’ailleurs !

    J’ai cependant un problème lorsqu’il s’agit de fermer le diaporama. J’aimerai supprimer l’ensemble des addChild(…) mais je n’arrive pas a supprimer toutes les miniatures qui sont construites à partir de addChild(uil).

    Comment pourrai-je supprimer ces miniatures. J’avou que j’ai déjà passer pas mal d’heures la nuit dernière à essayer….sans résultat.

    Merci !

    Jean Pierre

  6. johnnybreizh
    Posté le 08/02/2011 à 6h01

    Bonjour,

    Si je mets le code dans un movie clip, les images s’affichent mais aucunes interactions n’est possible…
    Si je mets le code dans la scène principale tout fonctionne bien.

    Comment puis-je faire pour faire fonctionner le code dans un movie clip ?

    Merci beaucoup

    JB

  7. François
    Posté le 07/02/2011 à 23h27

    Salut, merci pour le soutien…
    Ce que tu peux faire c’est générer ton fichier XML via PHP

    Ca va va lister tous les fichiers de ton dossier:

    <?php
    if ($handle = opendir(‘cheminvers/tondossier/’)) {
    while (false !== ($file = readdir($handle))) {
    if ($file != "." && $file != "..") {
    echo "$file\n";

    }
    }
    closedir($handle);
    }
    ?>
    J’ai chopé ca sur Php.net

    Après tu peux faire un echo avec tes balises XML…

    un peu comme le tuto sur les Flux RSS sur Snoupix smile

    a+

  8. Benach
    Posté le 03/02/2011 à 3h17

    Bonjour tout le monde.

    Effectivement cela fait plaisir de voir des gens qui ce décarcasse expliquer afin que d’autre comprennent plus rapidement.

    Par contre moi j’ai un autre souci c’est que toute ma galerie est en place (fichier swf, html, xml) tout fonctionne parfaitement en locale et sur mon site web mais malheureusement je me sert de ma galerie pour des soirées organisé par mon asso et ce sont des centaines de photos et je me vois mal me générer le fichier xml en entier pour les centaines de photos a charger. Je sais que simpleviewer en passant par Adobe génère ce fichier mais je ne mis connait pas assez bien script car ma galerie diffère beaucoup de celle-ci.
    Y t-il une solution a mon problème, c’est pas que je sois feignant mais quand même!!

    Merci par avance pour votre aide.

  9. François
    Posté le 28/01/2011 à 20h22

    Merci pour tous vos commentaires.
    Je ne peux pas répondre à toutes vos questions malheureusement.

    Pour Coline,
    il faudrait que tu mettes les miniatures et la photo principale dans un clip
    et puis tu fais ton_clip.visible = false; quand tu changes de menu smile

    a+

  10. Coline
    Posté le 24/01/2011 à 16h11

    Bonjour,

    Merci beaucoup pour le tuto, il est super facile à comprendre et un rendu très sympa.

    Cependant j’ai quelques petits soucis : j’ai intégré cette galerie à mon site, le problème c’est que lorsque je passe à une autre rubrique de mon site, la galerie reste visible sur ces autres pages.

    Comment puis je faire pour que la galerie s’enlève lorsque je passe à un autre menu?

    Merci,

  11. Shade
    Posté le 20/01/2011 à 8h40

    Bonjour,

    J’aimerais piloter le changement des images via javascript. J’ai ajouté un callback vers la fonction changeImage, mais apparemment il n’aime guère l’opération. Je suppose que les informations de la fonction se servent de l’event, mais je ne vois pas comment l’introduire dans mon callback

    ExternalInterface.addCallback("changeImage", changeImage);

    merci,

  12. colas
    Posté le 19/01/2011 à 16h26

    Bonjour,

    Merci beaucoup pour ce tuto! Il fonctionne tres bien. Par contre je voudrais y apporter quelques modifications mais étant débutant en flash j’ai un peu de mal! pour commencer j’ai agrandi la taille de la scène et vu que mes photos ne sont pas toutes de la même taille j’aimerai pouvoir les centrer en hauteur pour que ce soit plus joli.
    Ensuite j’aimerai enlever le "chargement en cours" qui apparait toujours derriere les images. Est-ce possible?

    Merci pour votre aide

  13. Benach
    Posté le 03/02/2011 à 3h15

    Bonjour tout le monde.

    Effectivement cela fait plaisir de voir des gens qui ce décarcasse expliquer afin que d’autre comprennent plus rapidement.
    Par contre moi j’ai un autre souci c’est que toute ma galerie est en place (fichier swf, html, xml) tout fonctionne parfaitement en locale et sur mon site web mais malheureusement je me sert de ma galerie pour des soirées organisé par mon asso et ce sont des centaines de photos et je me vois mal me générer le fichier xml en entier pour les centaines de photos a charger. Je sais que simpleviewer en passant par Adobe génère ce fichier mais je ne mis connait pas assez bien script car ma galerie diffère beaucoup de celle-ci.
    Y t-il une solution a mon problème, c’est pas que je sois feignant mais quand même!!

    Merci par avance pour votre aide.

  14. atn
    Posté le 17/03/2011 à 19h17

    Salut,

    Merci pour le tuto, il est super bien foutu.

    Je cherche maintenant à centrer le point d’ancrage des miniatures importées afin qu’elles restent centrées quand l’effet tween est appliqué.

    C’est possible?

    Merci

  15. skyliner
    Posté le 08/01/2011 à 17h37

    bonjour,

    Comment peux-t-on avoir le même code en AS3 orienté objet ?

    j’ai mis :
    package { …

    mais ca ne m’affiche plus rien !

  16. milano123
    Posté le 28/12/2010 à 14h26

    Bonjour,

    merci pour ce tuto, cependant, je voudrai simplement changer les images ainsi que les miniatures. Je ne sais pas comment faire. J’ai ouvert le fichier galerie.fla dans adobe Flash. Ensuite dans action, et puis je suis bloqué. Pouvez-vous m’aidez ? merci smile

  17. Gruguir
    Posté le 22/12/2010 à 8h10

    finalement j’ai fini par trouver une méthode pour appeler une page web.

    J’imagine que mon code est bien sale et pourrait tenir sur 3 lignes mais au cas où ca puisse être utile a quelqu’un :

    var url:String;
    var texteUrl:TextField = new TextField();
    texteUrl.text =  »;
    photoPrincipale.addEventListener(MouseEvent.CLICK, openUrl);

    texteUrl.text = monXML.image[1].attribute("url");
    (et l’attribut url="http://…&quot; dans le xml)

    (dans la fonction clicImage : )
    url=monXML.image[e.currentTarget.name].attribute("url");

    (dans la fonction changeImage) texteUrl.text = url;

    function openUrl(e:Event):void{

    if(texteUrl.text){
    var url:String = texteUrl.text;
    var request:URLRequest = new URLRequest(url);

    navigateToURL(request, ‘_blank’);
    }
    }

  18. Gruguir
    Posté le 22/12/2010 à 6h29

    Merci beaucoup pour ce tuto !

    Je bataille depuis longtemps pour tenter de cibler des url dans le xml afin d’ouvrir une nouvelle page web; si quelqu’un a des infos, des liens qui pourraient m’orienter dans la bonne direction je suis preneur.

  19. Tristan
    Posté le 04/12/2010 à 17h57

    Super Tuto. Merci beaucoup pour cette belle galerie flash!

  20. Ienien
    Posté le 14/11/2010 à 18h53

    Désolé mais je n’ai pas mis mon code, le voici :

    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import fl.containers.UILoader;

    import fl.controls.ProgressBar;
    import fl.transitions.Tween;
    import fl.transitions.easing.*;
    import fl.transitions.TweenEvent;
    import flash.events.*;
    import flash.text.*;
    import flash.filters.*;

    //définitions du dossier image

    var dossierImage:String = ‘images/’;

    //Chargeur du fichier XML
    var chargeur:URLLoader = new URLLoader ();
    var adresse:URLRequest = new URLRequest("galerie.xml");

    chargeur.load(adresse);
    chargeur.addEventListener(Event.COMPLETE, finDuChargementXML);

    //Une fois que le fichier XML est chargé…
    function finDuChargementXML(evt:Event):void
    {
    //Objet XML
    var monXML:XML = new XML(evt.target.data);

    //Variable qui contiendra l’image qui est selectionnée
    var select:String;

    ///Gestion des images
    for (var i:String in monXML.image)
    {
    var uil:UILoader = new UILoader();
    //uil.source = dossierImage + monXML.image[i].attribute("src");

    uil.load(new URLRequest(dossierImage + monXML.image[i].attribute("src")));

    uil.buttonMode = false;
    uil.name = i;
    uil.x = 0;

    uil.y = -840;
    uil.y += int((int(i)/10))*80;
    if (int(i) % 10 != 0)
    {
    uil.x += (int(i)%10)*80;
    }

    uil.width = uil.height = 80;
    uil.scaleContent = true;
    uil.autoLoad = true;
    this.addChild(uil);
    }
    }

  21. Ienien
    Posté le 14/11/2010 à 18h52

    Bonsoir,
    attaquant le chargement d’image via du xml j’ai trouvé votre tuto au bon moment. J’ai réussi à l’adapter à ce que je cherche à faire, à savoir afficher mes photos, sans chercher à cliquer dessus pour les agrandir.

    Je cherche maintenant à déplacer la "planche photo" obtenue verticalement en rajoutant 2 boutons de déplacer. Et là je coince.
    Pourriez-vous m’aider je suis largué ?
    Merci
    Ienien

  22. Cadet
    Posté le 29/09/2010 à 17h33

    bonjour,

    un peu novice dans la partie !
    j’ai essayé d’intégre la galerie dans ma page web, toutefois j’ai "chargement en cours" qui s’affiche est rien d’autre qui suite.
    D’où peut venir l’erreur svp ? (la syntaxe est bonne j’ai revérifiée).
    d’ailleurs que doit-on mettre dans la page web où doit s’afficher la galerie càd quel code entre les div pour renvoyer au fichier galerie.swf ?
    merci beaucoup je suis un peu larguée.

  23. jeremy74570
    Posté le 15/09/2010 à 21h13

    [citation][de]Réponse à François:[/de]Réponse à ninine2002:Bonjour,
    le tuto est très sympa et bien réalisé, cependant je n’arrive pas à ouvrir le fichier flash source…
    J’ai Adobe CS3, comment puis-je faire ?

    Euh ouai le fichier a été fait sur CS4 et au niveau de la compatibilité c’est pas vraiment top.
    Sinon ce que tu peux faire c’est téléchargé la version d’eval CS4 sur Adobe et le convertir ensuite pour CS3…Sinon un copier coller du code semble plus rapide smile[/citation]

  24. jeremy74570
    Posté le 15/09/2010 à 20h45

    Bonjour a tous !
    tout dabor un grand merci pour se tuto qui ma bocou apporter en terme de savoir nivo as. mais etant debutant , kelkun pourai il mexpliker comment installer un scroll bar pourvoir mettre plus d’image
    merci d’avance

  25. jeremy
    Posté le 15/09/2010 à 19h47

    Bonjour a tous !

    tout dabor un grand merci pour se tuto qui ma bocou apporter en terme de savoir nivo as. mais etant debutant , kelkun pourai il mexpliker comment installer un scroll bar pourvoir mettre plus d’image
    merci d’avance

1 Trackback

  1. [...] d'interfaces de site web, en passant par l'ActionScript, avec Flash & Flex.Galerie d'images AS3/XMLCe tutoriel va vous apprendre à manipuler en ActionScript 3 un document XML afin d'en extraire du contenu. [...]

Laisser un commentaire

Votre e-mail ne sera jamais publié ni communiqué. Les champs obligatoires sont indiqués par *

*
*

Vous pouvez utiliser ces balises et attributs HTML : <a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <strike> <strong>